Flex Reader on Google App Engine

package net.ivanidris.flexreader
{
   import com.adobe.serialization.json.JSON;
 
   import flash.events.Event;
   import flash.events.IOErrorEvent;
   import flash.events.KeyboardEvent;
   import flash.external.ExternalInterface;
   import flash.net.URLLoader;
   import flash.net.URLRequest;
   import flash.net.URLRequestMethod;
   import flash.net.URLVariables;
   import flash.net.navigateToURL;
 
   import mx.containers.GridItem;
   import mx.containers.GridRow;
   import mx.controls.Label;
   import mx.managers.PopUpManager;
 
   import net.ivanidris.flex.Counter;
   import net.ivanidris.flexreader.windows.AddComment;
   import net.ivanidris.flex.Bookmarks;
 
   public class FeedRequest
   {
        private var loader:URLLoader;
        private var app;
        private var counter:Counter;
        private var entries:FeedEntryCollection; 
        private var feedLinks:Array;
 
        public function FeedRequest(app, entries:FeedEntryCollection, 
         counter:Counter, feedLinks:Array):void {
         this.app = app;
            this.entries = entries; 
            this.counter = counter;
            this.feedLinks = feedLinks;
        }
 
        public function initGrid():void {
            this.app.readerGrid.setFocus();
            this.app.readerGrid.addEventListener(Event.ACTIVATE, getFocusBack);
            this.app.readerGrid.addEventListener(KeyboardEvent.KEY_DOWN, onKeyDown);
 
            for(var i:uint = 0; i < 9; i++) {
               var row:GridRow = new GridRow();
               var item:GridItem = new GridItem();
               var label:Label = new Label();
 
                item.addChild(label);
                row.addChild(item);
                this.app.readerGrid.addChild(row);
            }
        }
 
        public function getFeed():void {
         try {
               var url:String = '/feed';
               var request:URLRequest = new URLRequest(url);
                var variables:URLVariables = new URLVariables();
 
            variables.feedLinks = escape(JSON.encode(this.feedLinks));
 
            request.data = variables;
            request.method = URLRequestMethod.POST;
               loader = new URLLoader(request);
            loader.addEventListener(IOErrorEvent.IO_ERROR, onIOError);
               loader.addEventListener(Event.COMPLETE, onServerResponse);
            }
            catch(e:Error) {
               trace(e.message + e.getStackTrace());
            }
        }
 
        public function onServerResponse(e:Event):void {
              loadResults();
       }
 
       private function onIOError(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }
 
 
       public function getFocusBack(e:Event):void {
         setStyle(counter.get());
       }
 
       public function updateDisplay():void {
         var s:String = '#' + ( counter.get() + 1 ) ; 
            this.app.currentDisplay.text = s + ' Feed ' + this.entries.getFeedLink(counter.get()); 
       }
 
       public function onKeyDown(e:KeyboardEvent) :void{
         if(e.target.name.indexOf('Grid') < 0) {
            return;
         }
 
            if(String.fromCharCode(e.charCode) == 'j' ) {
               var isNotLast:Boolean = counter.increment();
               setStyle(counter.get());
               updateDisplay();
               this.app.display.text = this.entries.getMarkedNumber() + '/' +  (counter.getMax() + 1) + ' read';
 
               if((counter.get() - 1) >= 0) {
                  this.entries.setMarked(counter.get() - 1);
               }
 
                // move on
                if(!isNotLast) {
                  getFeed();
                } 
            }
 
            if(String.fromCharCode(e.charCode) == 'k' ) {
               counter.decrement();
               updateDisplay();
               setStyle(counter.get());
            }
 
            if(String.fromCharCode(e.charCode) == 'o' ) {
               navigateToURL(new URLRequest( this.entries.getUrl(counter.get())));
            }
 
            if(String.fromCharCode(e.charCode) == 'b' ) {
               var bookmarksWindow:Bookmarks =
                    Bookmarks(PopUpManager.createPopUp(this.app, Bookmarks, false));
                PopUpManager.centerPopUp(bookmarksWindow);
               bookmarksWindow.title = "Add Bookmark";   
               bookmarksWindow.url.text = this.entries.getUrl(counter.get());
               bookmarksWindow.t.text = this.entries.getTitle(counter.get());
            }
 
            if(String.fromCharCode(e.charCode) == 'c' ) {
               var commentsWindow:AddComment =
                    AddComment(PopUpManager.createPopUp(this.app, AddComment, false));
               commentsWindow.url.text = this.entries.getUrl(counter.get());
               commentsWindow.t.text = this.entries.getTitle(counter.get());
            }
       }
 
      public function loadResults():void {
          try {
                var json:Object = JSON.decode(unescape(loader.data));
 
                if(json == null || json.length == "") {
                  trace('Nothing to do ' + loader.data);
                  return;
                }
 
                var currentFeed:String = json[0].feedLink;
 
                if(this.feedLinks.indexOf(currentFeed) < 0) {
                    this.feedLinks.push(currentFeed);
                }
 
                // must not do  anything if nothing is added
                var newAdded:Boolean = false;
 
                for each(var i in json[1].entries) {
                  var feedEntry:FeedEntry = new FeedEntry();
                    feedEntry.title = i.title;
                    feedEntry.url = i.url;
                    feedEntry.content = i.content;
                    feedEntry.feedLink = currentFeed;
 
                    if(this.entries.contains(feedEntry)) { 
                     continue;
                    }
 
                    newAdded = true;
                    this.entries.add(feedEntry);
                }
 
                if(newAdded) {
                  counter.setMax(this.entries.len());
                  setStyle(0);
                }
 
              } catch(ignored:Error) {
                   trace(ignored.message + ignored.getStackTrace());
                    trace('Error decoding JSON datan' + loader.data);
              }
      }
 
      public function setStyle(index:Number):void {
           ExternalInterface.call("setContent", this.entries.getContent(index));
 
            var numEntries:uint = this.entries.len();
 
            for(var i:uint = 0; i < this.app.readerGrid.numChildren; i++) {
               var row = this.app.readerGrid.getChildAt(i);
 
               if(row != null) {
                      if(i == 0) {
                     row.setFocus();
                        row.drawFocus(true);
                    }
 
                    if((index + i) < numEntries) {
                        row.getChildAt(0).getChildAt(0).text = this.entries.getTitle(index + i);
 
                        if(this.entries.getMarked(index + i)) {
                            row.getChildAt(0).getChildAt(0).setStyle('color', '#FF0000');       
                        }
                    }
                    else {
                        row.getChildAt(0).getChildAt(0).text = "";
                    }
               } 
            }
      }
    }
}